기술문서 ID P_000049
HowTo DEXTUpload professional 다운로드 사용 시 다국어 처리
에러코드
태그 DEXTUpload Pro 기능구현
작성일 2010-03-19
문제

파일 다운로드 시 다국어 처리를 위한 인코딩 설정.

해결

다운로드 URL 인코딩 처리를 합니다.

아래와 같이 적용 후 유니코드(UTF-8)형식으로 저장합니다.

 

Upload.asp

<%@ Language=VBScript %>

<%

old_codepage = Session.CodePage

Session.CodePage = "65001"

%>

<HTML>

<HEAD>

<!----------------------------- UTF-8 ----------------------------->

<META http-equiv="Content-Type" content="text/html; charset=utf-8" >

<!----------------------------------------------------------------->

</HEAD>

<BODY>

<form name="write_form" enctype="multipart/form-data" method="post" action="upload_Process.asp">

                 

                  Simple Download<br><br>

                  Select the file to upload:

                 

                  <input type="file" name="file"><br><br>

 

                  1. 업로드 파일 저장경로는 C:\TEMP입니다.<br>

                  2.'찾아보기' 버튼을 지원하지 않는 브라우저인 경우 최신 버전의 브라우저로 업데이트 하시기 바랍니다.<br>

                  3. 예제는 우선 업로드를 다음 업로드한 파일을 이용하여 다운로드 예제가 실행 됩니다<br><br>

 

                  <input type="submit" name="Upload" value="Upload">

                 

</form>

</BODY>

</HTML>

<%

Session.CodePage = old_codepage

%>

 

 

upload_Process.asp

<%@ Language=VBScript %>

<%

                  old_codepage = Session.CodePage

                  Session.CodePage = "65001"

%>

<HTML>

<HEAD>

<!----------------------------- UTF-8 ----------------------------->

<META http-equiv="Content-Type" content="text/html; charset=utf-8" >

<!----------------------------------------------------------------->

</HEAD>

<BODY>

<%

 

set uploadform=server.CreateObject("DEXT.FileUpload")

 

uploadform.DefaultPath="C:\TEMP"

 

FilePath = uploadform.Save()

%>

Original Path : <%= uploadform("file").FilePath %><br>

Upload Path : <%= FilePath %><br>

File Size : <%= uploadform("file").FileLen %> bytes <br>

MimeType : <%= uploadform("file").MimeType %> <br>

LastSavedFileName : <%= uploadform("file").LastSavedFileName %><br>

LastSavedFilePath : <%= uploadform("file").LastSavedFilePath %><br>

<b><a href="download.asp?filepath=<%=Server.UrlEncode(FilePath)%>&filename=<%=Server.UrlEncode(uploadform("file").filename)%>">DOWNLOAD DATA!!</a></b>

</BODY>

</HTML>

<%

Set uploadform =nothing

 

Session.CodePage = old_codepage

%>

 

 

download.asp

<%@ Language=VBScript%>

<%

 

old_codepage = Session.CodePage

Session.CodePage = "65001"

 

filepath = request("filepath")

filename = request("filename")

 

encodename = Server.UrlEncode(filename)

delimiter  = InStrRev(encodename, "%2E")

 

if delimiter <> 0 then

tempname   = Left  ( encodename,  delimiter - 1 )

temptype   = Right ( encodename,  Len(encodename) - delimiter - 2 )

encodename = replace( tempname & "." & temptype, "+" ,"%20" )

end if

 

'Response.AddHeader "Content-Disposition", "inline;filename=" & encodename

Response.AddHeader "Content-Disposition", "attachment;filename=" & encodename

 

'다운로드 개체생성

Set objDownload = Server.CreateObject("DEXT.FileDownload")

objDownload.Download filepath, filename, true, false

 

Set objDownload = Nothing

Session.CodePage = old_codepage

 

%>